[R] Migrazione DBLOG-WordPress (non mi linciate!)

<!--#include virtual="/mdb-database/inc_costanti.asp"-->
<!--#include file="inc_db.asp"-->
<!--#include file="inc_funzioni.asp"-->
<% 
    'dBlog 2.0 CMS Open Source
    'Versione file 2.0.0
    'Autore: Adriano Amalfi
    'FUNZIONE: questo script si occupa di generare il export per importarlo in wordpress

    Dim SQLArticoli, RSArticoli, SQLCommenti, RSCommenti

    Response.ContentType = "text"

'CERCO GLI ARTICOLI
    SQLArticoli = " SELECT [ID], [Autore], [Sezione], [Titolo], [Testo], [Data], [Ora] FROM Articoli WHERE Articoli.Data <= '"& DataToStr(Date()) &"' AND NOT Articoli.Bozza ORDER BY Articoli.Data DESC, Articoli.Ora DESC "
    Set RSArticoli = Server.CreateObject("ADODB.Recordset")
    RSArticoli.Open SQLArticoli, Conn, 1, 3

    If NOT RSArticoli.EOF Then
        Do While NOT RSArticoli.EOF
            ' ESPORTO GLI ARTICOLI 
            FID = RSArticoli("ID")
            Response.Write "TITLE: "& NoHTML(DecodeEntities(RSArticoli("Titolo"))) & VbCrLf
            Response.Write "AUTHOR: " & RSArticoli("Autore") & VbCrLf
            Response.Write "DATE:"& Mid(RSArticoli("Data"), 1, 4) & "/" & Mid(RSArticoli("Data"), 5, 2) & "/" & Mid(RSArticoli("Data"), 7, 2) & " " & Mid(RSArticoli("Ora"), 1, 2) & ":" & Mid(RSArticoli("Ora"), 3, 2) & ":" & Mid(RSArticoli("Ora"), 5, 2) & VbCrLf
            Response.Write "PRIMARY CATEGORY: " & RSArticoli("Sezione") & VbCrLf
            Response.Write "CATEGORY: dblog" & VbCrLf
            Response.Write "STATUS: publish" & VbCrLf 
            Response.Write "-----" & VbCrLf
            Response.Write "BODY:" & VbCrLf
            Response.Write Replace(FileToVar(Path_DirPublic & RSArticoli("Testo"), 0), Tag_Trailer, "")& VbCrLf
            Response.Write "-----" & VbCrLf
            ' ESPORTO I COMMENTI
            SQLCommenti = " SELECT * FROM [Commenti] WHERE Commenti.IDArticolo = "& cInt(FID) &" AND Commenti.IDArticolo <> 0 "
            Set RSCommenti = Server.CreateObject("ADODB.Recordset")
            RSCommenti.Open SQLCommenti, Conn, 1, 3
            If NOT RSCommenti.EOF Then
                Do While NOT RSCommenti.EOF
                    Response.Write "COMMENT:" & VbCrLf
                    Response.Write "AUTHOR: "& RSCommenti("Autore") & VbCrLf
                    Response.Write "DATE:"& Mid(RSCommenti("Data"), 1, 4) & "/" & Mid(RSCommenti("Data"), 5, 2) & "/" & Mid(RSCommenti("Data"), 7, 2) & " " & Mid(RSCommenti("Ora"), 1, 2) & ":" & Mid(RSCommenti("Ora"), 3, 2) & ":" & Mid(RSCommenti("Ora"), 5, 2) & VbCrLf
                    Response.Write "IP: " & RSCommenti("IP") & VbCrLf
                    Response.Write "EMAIL: " & RSCommenti("Link") & VbCrLf
                    Response.Write RSCommenti("Testo") & VbCrLf
                    Response.Write "-----" & VbCrLf
                    RSCommenti.MoveNext
                Loop
            End If
            RSArticoli.MoveNext
            Response.Write "--------" & VbCrLf
        Loop
    End If
    set RSCommenti = Nothing
    set RSArticoli = Nothing
    Conn.Close
    Set Conn = Nothing
%>